Is this a sensible way to compare two Treasury bonds?

Discuss all general (i.e. non-personal) investing questions and issues, investing news, and theory.
Post Reply
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Is this a sensible way to compare two 20-year, $1000 Treasury bonds?

Bond 1 has a 4.375% coupon and sells at a slight discount, for $99 per $100.
Bond 2 has a 4.750% coupon and sells at a premium, for $104 per $100.

If I bought 60 of Bond 1 at $990 each, they would cost $59,400.
If I bought 60 of Bond 2 at $1040 each, they would cost $62,400.

60 of Bond 1 would pay 4.375% x $1000 x 20 years x 60 bonds = $52,500 in interest.
60 of Bond 2 would pay 4.750% x $1000 x 20 years x 60 bonds = $57,000 in interest.

60 of Bond 2 would cost $3000 more to buy, but they would pay $4500 more in interest. Is their apparent $1500 advantage real? I understand that Yield to Maturity is what most investors look for, but in the real bonds on which I based this question, the Yield to Maturity was slightly higher for Bond 1, and if Yield to Maturity is a better comparison than the above calculations, what is it taking into account that the above calculations don't?
hudson
Posts: 7032
Joined: Fri Apr 06, 2007 9:15 am

Re: Is this a sensible way to compare two Treasury bonds?

Post by hudson »

Mevni wrote: Tue Feb 06, 2024 7:54 pm Is this a sensible way to compare two 20-year, $1000 Treasury bonds?

Bond 1 has a 4.375% coupon and sells at a slight discount, for $99 per $100.
Bond 2 has a 4.750% coupon and sells at a premium, for $104 per $100.

If I bought 60 of Bond 1 at $990 each, they would cost $59,400.
If I bought 60 of Bond 2 at $1040 each, they would cost $62,400.

60 of Bond 1 would pay 4.375% x $1000 x 20 years x 60 bonds = $52,500 in interest.
60 of Bond 2 would pay 4.750% x $1000 x 20 years x 60 bonds = $57,000 in interest.

60 of Bond 2 would cost $3000 more to buy, but they would pay $4500 more in interest. Is their apparent $1500 advantage real? I understand that Yield to Maturity is what most investors look for, but in the real bonds on which I based this question, the Yield to Maturity was slightly higher for Bond 1, and if Yield to Maturity is a better comparison than the above calculations, what is it taking into account that the above calculations don't?
I chose the duration and check yield to maturity. That's all.
I also check brokered and bank CDs.
I want the best deal after taxes.
km91
Posts: 1367
Joined: Wed Oct 13, 2021 12:32 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by km91 »

Mevni wrote: Tue Feb 06, 2024 7:54 pm what is it taking into account that the above calculations don't?
It's the upfront premium. A more apples to apples comparison is to assume an equal purchase amount of each bond, $62,400 for bond 1 and bond 2, not equal amounts of face value. With bond 1 you have an extra 3k that can also be invested in the bond or other investments. In any case, yield to maturity is the most relevant return measure when comparing bonds
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Thank you, km91; that makes complete sense. I barely paid attention to what I could do with that extra $3000; it would earn much more than the $1500 difference in interest based on the the coupons and face values. If there are bonds with much lower coupons, such as 3.75%, but a higher YTM, is there any disadvantage to buying them, such as if I wanted to sell them before maturity?
User avatar
#Cruncher
Posts: 3950
Joined: Fri May 14, 2010 2:33 am
Location: New York City
Contact:

Re: Is this a sensible way to compare two Treasury bonds?

Post by #Cruncher »

km91 wrote: Tue Feb 06, 2024 10:13 pmA more apples to apples comparison is to assume an equal purchase amount of each bond, $62,400 for bond 1 and bond 2, not equal amounts of face value.
Indeed. $62,400 would purchase $63,030 face value of the bond selling at a discount with the higher yield-to-maturity (YTM).
(62,400 = 63,030 * 0.99)
I show this option in column D of the table below. As shown on rows 10 and 33 it produces $1,182 more profit than the premium bond in column C. (Rows 5 and 34 use the RATE and IRR functions to calculate the YTM. For simplicity I'm assuming interest is paid annually.)

Code: Select all

Row       Col A    Col B    Col C    Col D   Formula in Col B Copied Right
  2        Term       20
  3      Coupon   4.375%   4.750%   4.375%
  4       Price       99      104       99
  5         YTM   4.452%   4.444%   4.452%  =RATE($B2,100*B3,-B4,100,0)
  6  Face value   60,000   60,000   63,030
  7        Cost  -59,400  -62,400  -62,400  =-B6*(B4/100)
  8    Interest   52,500   57,000   55,151  =B6*$B2*B3
  9  Redemption   60,000   60,000   63,030  =B6
 10      Profit   53,100   54,600   55,782  =SUM(B7:B9)
 11        Year  ------- Cash Flow -------

Code: Select all

 12           0  -59,400  -62,400  -62,400  =B7
 13           1    2,625    2,850    2,758  =B$6*(B$3+IF($A13=$B$2,1,0))
 14           2    2,625    2,850    2,758   | | |
 15           3    2,625    2,850    2,758   | | |
 16           4    2,625    2,850    2,758   | | |
 17           5    2,625    2,850    2,758   | | |
 18           6    2,625    2,850    2,758   | | |
 19           7    2,625    2,850    2,758   | | |
 20           8    2,625    2,850    2,758   | | |
 21           9    2,625    2,850    2,758   | | |
 22          10    2,625    2,850    2,758   | | |
 23          11    2,625    2,850    2,758   | | |
 24          12    2,625    2,850    2,758   | | |
 25          13    2,625    2,850    2,758   | | |
 26          14    2,625    2,850    2,758   | | |
 27          15    2,625    2,850    2,758   | | |
 28          16    2,625    2,850    2,758   | | |
 29          17    2,625    2,850    2,758   | | |
 30          18    2,625    2,850    2,758   | | |
 31          19    2,625    2,850    2,758   v v v
 32          20   62,625   62,850   65,788  =B$6*(B$3+IF($A32=$B$2,1,0))
 33      Profit   53,100   54,600   55,782  =SUM(B12:B32)
 34      Return   4.452%   4.444%   4.452%  =IRR(B12:B32)
Mevni wrote: Tue Feb 06, 2024 11:40 pmIf there are bonds with much lower coupons, such as 3.75%, but a higher YTM, is there any disadvantage to buying them, such as if I wanted to sell them before maturity?
Possibly. But at worst only a small disadvantage even if the yield of the lower coupon bond was the same as the one with the higher coupon. For example, let's compare two 20-year bonds both yielding 4.50%. One has a 3.75% coupon and the other a 4.75% coupon.

The following table compares the return after each year if one sold both bonds when their YTM had risen to 5.5%. In all cases the larger coupon bond performs a little better. Selling after one year, you'd lose 7.54% on the 3.75% coupon bond, but only 6.98% on the bond with the 4.75% coupon. But if one sold after nine years, the returns would be about the same: 3.69% for the smaller coupon bond [*] versus 3.74% for the one with the larger coupon. (The table uses the PV function as well as the RATE function.)

Code: Select all

Row       Col A    Col B     Col C   Formula in Col B Copied Right
  2        Term       20
  3     YTM now    4.50%
  4  YTM future    5.50%
  5      Coupon    3.75%     4.75%
  6       Price  90.244%  103.252%  =-PV($B3,$B2,B5,1,0)
  7        Year   Return    Return

Code: Select all

  8           1   -7.54%    -6.98%  =RATE($A8,B$5,-B$6,-PV($B$4,$B$2-$A8,B$5,1,0),0)
  9           2   -1.38%    -1.09%   | | |
 10           3    0.76%     0.95%   | | |
 11           4    1.85%     1.99%   | | |
 12           5    2.51%     2.62%   | | |
 13           6    2.95%     3.04%   | | |
 14           7    3.27%     3.34%   | | |
 15           8    3.50%     3.56%   | | |
 16           9    3.69%     3.74%   | | |  <=== [*]
 17          10    3.84%     3.88%   | | |
 18          11    3.96%     3.99%   | | |
 19          12    4.06%     4.09%   | | |
 20          13    4.14%     4.17%   | | |
 21          14    4.22%     4.24%   | | |
 22          15    4.28%     4.29%   | | |
 23          16    4.33%     4.35%   | | |
 24          17    4.38%     4.39%   | | |
 25          18    4.43%     4.43%   | | |
 26          19    4.47%     4.47%   v v v
 27          20    4.50%     4.50%  =RATE($A27,B$5,-B$6,-PV($B$4,$B$2-$A27,B$5,1,0),0)
* Detail of 3.69% return calculation for 3.75% coupon bond after nine years:

Code: Select all

85.838 =  -PV(5.5%, 11, 3.75,         100,     0) = price of bond with 11 years remaining
 3.69% = RATE(       9, 3.75, -90.244, 85.838, 0) = return over first 9 years
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Thank you for a thorough and helpful reply, #cruncher. In your comparison of what would happen if I sold each bond, you assume the bond prices have fallen. I would be very interested in how you compare them if their prices have risen, as seems likely if the Fed cuts interest rates.
User avatar
#Cruncher
Posts: 3950
Joined: Fri May 14, 2010 2:33 am
Location: New York City
Contact:

Re: Is this a sensible way to compare two Treasury bonds?

Post by #Cruncher »

Mevni wrote: Wed Feb 07, 2024 3:04 pmIn your comparison of what would happen if I sold each bond, you assume the bond prices have fallen. I would be very interested in how you compare them if their prices have risen, ...
The table below shows the return for both bonds if they are sold after one year with various assumptions for the yield on 19-year bonds at that time: from 0% all the way up to 9.5%. For example, if the YTM was 3.5% after one year, the 3-3/4% coupon bond would gain 18.76% while the 4-3/4% coupon bond would gain only 18.05%. [*]

For two bonds with the same term to maturity, the one with the smaller coupon will have a longer duration. This means it will be more sensitive to changes in yields. If yields go down, its price will rise more. If they go up, its price will fall more.

Code: Select all

Row       Col A     Col B     Col C   Formula in Col B Copied Right
  2        Term        20
  3     YTM now     4.50%
  4   Year sell         1  <===
  5      Coupon     3.75%     4.75%
  6       Price   90.244%  103.252%  =-PV($B3,$B2,B5,1,0)
  7  Future YTM    Return    Return

Code: Select all

  8        0.0%    93.92%    88.86%  =RATE($B$4,B$5,-B$6,-PV($A8,$B$2-$B$4,B$5,1,0),0)
  9        0.5%    80.09%    75.88%   | | |
 10        1.0%    67.46%    64.01%   | | |
 11        1.5%    55.92%    53.15%   | | |
 12        2.0%    45.37%    43.21%   | | |
 13        2.5%    35.71%    34.09%   | | |
 14        3.0%    26.87%    25.73%   | | |
 15        3.5%    18.76%    18.05%   | | |  <=== [*]
 16        4.0%    11.33%    10.99%   | | |
 17        4.5%     4.50%     4.50%   | | |
 18        5.0%    -1.77%    -1.48%   | | |
 19        5.5%    -7.54%    -6.98%   | | |
 20        6.0%   -12.85%   -12.06%   | | |
 21        6.5%   -17.75%   -16.74%   | | |
 22        7.0%   -22.26%   -21.07%   | | |
 23        7.5%   -26.42%   -25.07%   | | |
 24        8.0%   -30.26%   -28.78%   | | |
 25        8.5%   -33.81%   -32.21%   | | |
 26        9.0%   -37.10%   -35.39%   v v v
 27        9.5%   -40.15%   -38.34%  =RATE($B$4,B$5,-B$6,-PV($A27,$B$2-$B$4,B$5,1,0),0)
* Calculation detail for both bonds when YTM after one year is 3.5%.

Code: Select all

3-3/4% coupon bond
  103.427 =  -PV(3.5%, 19, 3.75,            100,     0) = price of bond with 19 years remaining
   18.76% = RATE(       1, 3.75,   -90.244, 103.427, 0) = return over first year
   18.76% = (103.427 + 3.75) / 90.244 - 1               = simpler return calc when just 1 year
   14.61% =  103.427 / 90.244 - 1                       = increase in price
4-3/4% coupon bond
  117.137 =  -PV(3.5%,  19, 4.75,           100,     0) = price of bond with 19 years remaining
   18.05% = RATE(        1, 4.75, -103.252, 117.137, 0) = return over first year
   18.05% = (117.137 + 4.75) / 103.252 - 1              = simpler return calc when just 1 year
   13.45% =  117.137 / 103.252 - 1                      = increase in price
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Extremely helpful and interesting again, #cruncher; thank you!
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

This conversation got me interested in seeing how bond prices would change in years subsequent to the first. I eventually found a "Modified Duration" calculator that shows the percentage change in a bond's value in response to a 1% change in interest rates, depending on the YTM, coupon, payment frequency, and time remaining before the bond matures.
https://exploringfinance.com/bond-duration-calculator/
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Using Modified Duration, I compared the return on a hypothetical $10,000 worth of two 20-year Treasury bonds if sold three years from now with interest rates 1% lower than now. I know you can't buy partial bonds, but I compared $10,000 of each to make it an apples-to-apples comparison. My calculations surprised me by showing $10,000 worth of a premium bond with a higher coupon and lower YTM returning more than $10,000 worth of a discount bond with a lower coupon and higher YTM. I used two bonds that were actually available in small quantities a few days ago. I used the following calculator for the Modified Durations. I set its payment frequency to Annual to minimize the impact of its reinvesting the interest into the bond.

https://exploringfinance.com/bond-duration-calculator/

The bond with a 4.75% coupon, 4.38% YTM, and 104.778% price has a Modified Duration of 11.663 with 17 years left before maturity.
The bond with a 3.625% coupon, 4.48% YTM, and 88.773% price has a Modified Duration of 12.076 with 17 years left before maturity.

4.75% coupon, 4.38% YTM:
$10,000 / 1047.78 = 9.544 bonds.
Price value after 3 years would be $10,000 x 1.11663 = $11,166.30
Interest would be $9544 x 0.0475 x 3 = $1360.02 (If one could actually buy $10,000 worth, the face value would be $9544.)
Return: $12,526.32

3.625% coupon, 4.48% YTM:
$10,000 / 887.73 = 11.265 bonds.
Price value after 3 years would be $10,000 x 12.076 = $11,207.60
Interest would be $11,265 x 0.03625 x 3 = $1225.07
Return: $12,432.67
Last edited by Mevni on Sun Feb 11, 2024 7:27 pm, edited 1 time in total.
km91
Posts: 1367
Joined: Wed Oct 13, 2021 12:32 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by km91 »

Duration reflects the change in price for an instantaneous shift in the yield curve. Over 3 years the change in the bonds price is not simply a function of changing yields. The bonds' prices approach par over time. For the premium bond these effects are in opposite directions, a fall in yields raises the bonds price but the passage of time pulls the bonds price down to par. For the discount bond the effects are in the same direction, upward on price. There might be a calculation error with the second bond. Without doing the math I suspect the discount bond with lower coupons will see a higher total return over the three years
Topic Author
Mevni
Posts: 7
Joined: Tue Feb 06, 2024 7:38 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by Mevni »

Thank you, km91. I would think a calculator that accurately predicts the return on a bond if sold in a few years after interest rates had gradually dropped by 1% would be in high demand. Fidelity has a calculator in which you can specify Treasury bonds and enter the maturity date , settlement date, YTM, and coupon and get a graph of the bond's prices for a range of future YTMs. Does this calculator look more accurate, given your reservation about using Modified Duration?

https://digital.fidelity.com/prgw/digit ... yieldcalc/

While I was out hiking, I realized that, because the Modified Duration calculator reinvests the interest into the bond, unlike an actual Treasury bond, it slightly reduces the Modified Duration and therefore the comparative gain in response to a 1% lower interest rate for the bond with the higher coupon.
km91
Posts: 1367
Joined: Wed Oct 13, 2021 12:32 pm

Re: Is this a sensible way to compare two Treasury bonds?

Post by km91 »

You can probably use the calculator to price your two 20yr bonds as 17 year bonds. That should give you a sense of the prices of the bonds in three years for the range of YTMs that you can compare to the current prices
Post Reply