#Cruncher wrote: ↑Sat Feb 09, 2019 10:30 pmThe width of this maximum [49.95% marginal tax rate] hump can be many thousands of dollars if one has a lot of LTCG or qualified dividends.
The "width" of this hump also depends on the amount of Social Security Benefit as shown in the following table.
Code: Select all
Row Col A Col B Col C Col D Col E Col F Col G Col H
1 Single = 1, Joint = 2 1
2 LTCG & QDI 20,000
3 Deduction 12,000
4 50% threshold 25,000
5 85% threshold 34,000
6 Start LTCG 15% bracket 38,600
LTCG 15% Taxable SS 85% Hump 49.95% Marginal Rate
---------------- --------------- ------------------------
Start End Start End Start End Range
------ ------ ------ ------ ------ ------ ------
9 Adjusted Gross Income 50,600 70,600
10 Soc Security Benefit ------------------- Non-SS Ordinary Income ---------------------
Code: Select all
11 0 30,600 50,600 14,000 14,000 30,600 14,000
12 5,000 26,350 46,350 11,500 13,559 26,350 13,559
13 10,000 22,100 42,100 9,000 13,706 22,100 13,706
14 15,000 17,850 37,850 6,500 16,206 17,850 16,206
15 20,000 15,946 33,600 4,000 18,706 15,946 18,706 2,760
16 25,000 14,797 29,350 1,500 21,206 14,797 21,206 6,409
17 30,000 13,649 25,100 (1,000) 23,706 13,649 23,706 10,057
18 35,000 12,500 23,311 (3,500) 26,206 12,500 23,311 10,811
19 40,000 11,351 22,162 (6,000) 28,706 11,351 22,162 10,811
For example assume a single taxpayer with $20,000 of long term capital gains (LTCG) and qualified dividend income (QDI) and $20,000 of Social Security benefit taking the standard deduction in 2018. As shown in row 15, at non-SS ordinary income of $15,946 his LTCG & QDI starts being taxed at 15%. This continues until non-SS ordinary income reaches $33,600 when all $20,000 of the LTCG & QDI has been taxed at 15%.
Meanwhile non-SS ordinary income from $4,000 to $18,706 puts him in the "hump" where each $100 makes $85 of SS become taxable. The
intersection of these two ranges ($15,946 to $18,706) is where he'll incur the 49.95% marginal tax rate. Thus the "width" is only $2,760. But with higher SS the width can be as much as $10,811.
For those wishing to see the results for a different amount of LTCG & QDI or for a joint tax return, follow these steps:
- Select All, Copy, and Paste [ * ] the following at cell A1 of a blank Excel sheet.
Code: Select all
Single = 1, Joint = 2 1
LTCG & QDI 20000
Deduction =IF(B1=1,12000,24000)
50% threshold =IF(B1=1,25000,32000)
85% threshold =IF(B1=1,34000,44000)
Start LTCG 15% bracket =IF(B1=1,38600,77200)
LTCG/QDI 15% Taxable SS 85% Hump 49.95% Marginal Tax
Start End Start End Start End Range
Adjusted Gross Income =B6+B3 =B9+B2
Soc Security Benefit Non-SS Ordinary Income
0 =IF($A11>2*($B$5-B$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((B$9+0.5*$B$4+0.35*$B$5-0.425*$A11)/1.85+$A11/2-$B$5)>0.85*$A11,B$9-0.85*$A11,(B$9+0.5*$B$4+0.35*$B$5-0.425*$A11)/1.85),IF($A11>2*($B$4-B$9),(B$9-$A11*0.25+0.5*$B$4)/1.5,B$9))-$B$2 =IF($A11>2*($B$5-C$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((C$9+0.5*$B$4+0.35*$B$5-0.425*$A11)/1.85+$A11/2-$B$5)>0.85*$A11,C$9-0.85*$A11,(C$9+0.5*$B$4+0.35*$B$5-0.425*$A11)/1.85),IF($A11>2*($B$4-C$9),(C$9-$A11*0.25+0.5*$B$4)/1.5,C$9))-$B$2 =B$5-A11/2-$B$2 =D11+(0.85*$A11-0.5*MIN(A11,B$5-B$4))/0.85 =MAX(B11,D11) =MIN(C11,E11) =MAX(0,G11-F11)
5000 =IF($A12>2*($B$5-B$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((B$9+0.5*$B$4+0.35*$B$5-0.425*$A12)/1.85+$A12/2-$B$5)>0.85*$A12,B$9-0.85*$A12,(B$9+0.5*$B$4+0.35*$B$5-0.425*$A12)/1.85),IF($A12>2*($B$4-B$9),(B$9-$A12*0.25+0.5*$B$4)/1.5,B$9))-$B$2 =IF($A12>2*($B$5-C$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((C$9+0.5*$B$4+0.35*$B$5-0.425*$A12)/1.85+$A12/2-$B$5)>0.85*$A12,C$9-0.85*$A12,(C$9+0.5*$B$4+0.35*$B$5-0.425*$A12)/1.85),IF($A12>2*($B$4-C$9),(C$9-$A12*0.25+0.5*$B$4)/1.5,C$9))-$B$2 =B$5-A12/2-$B$2 =D12+(0.85*$A12-0.5*MIN(A12,B$5-B$4))/0.85 =MAX(B12,D12) =MIN(C12,E12) =MAX(0,G12-F12)
=2*A12-A11 =IF($A13>2*($B$5-B$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((B$9+0.5*$B$4+0.35*$B$5-0.425*$A13)/1.85+$A13/2-$B$5)>0.85*$A13,B$9-0.85*$A13,(B$9+0.5*$B$4+0.35*$B$5-0.425*$A13)/1.85),IF($A13>2*($B$4-B$9),(B$9-$A13*0.25+0.5*$B$4)/1.5,B$9))-$B$2 =IF($A13>2*($B$5-C$9+0.5*($B$5-$B$4)),IF(0.5*($B$5-$B$4)+0.85*((C$9+0.5*$B$4+0.35*$B$5-0.425*$A13)/1.85+$A13/2-$B$5)>0.85*$A13,C$9-0.85*$A13,(C$9+0.5*$B$4+0.35*$B$5-0.425*$A13)/1.85),IF($A13>2*($B$4-C$9),(C$9-$A13*0.25+0.5*$B$4)/1.5,C$9))-$B$2 =B$5-A13/2-$B$2 =D13+(0.85*$A13-0.5*MIN(A13,B$5-B$4))/0.85 =MAX(B13,D13) =MIN(C13,E13) =MAX(0,G13-F13)
- Format for readability.
- Copy row 13 down as far as needed.
- Revise cells B1, B2, B3, B6, A11, & A12 as needed.
To see the results graphically, use the Main sheet of my
Marginal Tax Rates spreadsheet.
* If you have trouble pasting, try "Paste Special" and "Text".