AGI, capital gains, and income interaction?

Non-investing personal finance issues including insurance, credit, real estate, taxes, employment and legal issues such as trusts and wills.
Post Reply
Topic Author
Morik
Posts: 1344
Joined: Tue Nov 25, 2014 11:26 am

AGI, capital gains, and income interaction?

Post by Morik »

I'm curious how things like capital gains interact with income.

I know in retirement some advice is that if you are in the 15% tax bracket you can fill it up with capital gains at 0% gains rate.

This got me thinking--how do these interact exactly?

Do capital gains go on 'top'? On the bottom?

Example: Lets say I have $30,000 in earned income, and $15,000 in capital gains. (Filing singly)

my AGI is $45,000.

What rates do I pay on my income?
(Brackets:
10% for $0 - $9,225
15% for $9,225 - $37,450
25% for $37,450 - $90,750
)

Do I pay the 10% on the first $9,225 of income, 15% on the other $20,775, and then 0% on the first $7,450 of capital gains, and the usual 15% gains rate on the next $7,550?
(I.e., capital gains add on at the top?)
Total Tax: $5171.25

Or do I pay 0% on all the capital gains, but then 15% on $22,450 ($37,450-$15,000) of income, and 25% on the other $7,550 of income?
(I.e., capital gains are filled in from the bottom?)
Total tax: $5225
terran
Posts: 3046
Joined: Sat Jan 10, 2015 9:50 pm

Re: AGI, capital gains, and income interaction?

Post by terran »

Morik wrote: Do I pay the 10% on the first $9,225 of income, 15% on the other $20,775, and then 0% on the first $7,450 of capital gains, and the usual 15% gains rate on the next $7,550?
(I.e., capital gains add on at the top?)
Total Tax: $5171.25
This one sounds right at first glance. You could mess around with https://turbotax.intuit.com/tax-tools/c ... taxcaster/ to get a better feel for things.
wannabeteacher
Posts: 72
Joined: Wed Sep 09, 2015 2:59 pm

Re: AGI, capital gains, and income interaction?

Post by wannabeteacher »

I do not understand what you mean by "top" and "bottom". I think you mean in the income section or adjustments to income. They are entered on some
line in the income section if my memory is right
cherijoh
Posts: 6591
Joined: Tue Feb 20, 2007 3:49 pm
Location: Charlotte NC

Re: AGI, capital gains, and income interaction?

Post by cherijoh »

Morik wrote:I'm curious how things like capital gains interact with income.

I know in retirement some advice is that if you are in the 15% tax bracket you can fill it up with capital gains at 0% gains rate.

This got me thinking--how do these interact exactly?

Do capital gains go on 'top'? On the bottom?
Have you tried to work through the capital gains worksheet? It can be found in the 1040 Instructions. For one thing you don't start with your AGI - you use your taxable income (after subtracting your exemption and either the standard or itemized deductions).
Grasshopper
Posts: 1209
Joined: Sat Oct 09, 2010 3:52 pm

Re: AGI, capital gains, and income interaction?

Post by Grasshopper »

+1 Form 1040 Qualified Dividends and Capital Gain Tax Worksheet 2014, Line 44. I spent maybe 2 hours making a spreadsheet using income info from other excel/google sheets, the only drawback is not having 2015 tax rates. :beer
kaneohe
Posts: 6786
Joined: Mon Sep 22, 2008 12:38 pm

Re: AGI, capital gains, and income interaction?

Post by kaneohe »

For a pictorial way of thinking about this, see tfb's stacked bar chart (12/11/11)here viewtopic.php?t=86849 The discussion is about qualified dividends but the same principle applies to LTCG.

You also need to take into account deductions/exemptions by subtracting them from AGI to get taxable income (also any adjustments such as
IRA deductions).
User avatar
#Cruncher
Posts: 3977
Joined: Fri May 14, 2010 2:33 am
Location: New York City
Contact:

Re: AGI, capital gains, and income interaction?

Post by #Cruncher »

Here is the stacked bar chart from this post I believe kaneohe is referring to:
Image

I've built an Excel sheet based on this chart to not only calculate the Federal tax but to also show what brackets the Qualified Dividend Income plus Long Term Capital Gain (QDI & LTCG) and the Ordinary Income fall into. Specifically I wanted to confirm this comment:
Houseblend in his post [url=http://www.bogleheads.org/forum/viewtopic.php?p=2585514#p2585514]Re: Interesting Argument in Favor of Roth[/url] wrote:If you are at the top of the 15% bracket for taxable income, and have qualified dividends or LTCG, then the next dollar of Roth conversions will be taxed at the marginal rate of 30%, not 25%.
Here is a calculation of 2015 for a single senior with no social security, a $4,000 personal exemption, a $7,850 standard deduction, and $10,000 of QDI / LTCG. In row 27 of column B he has $39,300 of ordinary income which pushes his Taxable Income right up to the top of the $37,450 15% bracket. Column C shows adding $10,000 of ordinary income which causes a 30% tax increase. The extra ordinary income is taxed at 15% plus the QDI / LTCG is now taxed at 15% instead of 0%. Column D shows adding another $10,000 which causes a 25% tax increase. The extra ordinary income is taxed at 25% while the QDI / LTCG remains taxed at 15%.

Code: Select all

Row      Col A                         Col B    Col C    Col D
---  -------------------               -----    -----    -----
 26  Tax exempt interest                   0        0        0
 27  Non-SS Ordinary Income           39,300   49,300   59,300
 28  LTCG & QDI                       10,000   10,000   10,000
 29  SS Benefits                           0        0        0
 32  Deductions & Exemptions          11,850   11,850   11,850
 38  Adjusted Gross Income            49,300   59,300   69,300
 39  Taxable Income                   37,450   47,450   57,450
 40  Taxable QDI & LTCG               10,000   10,000   10,000
 41  Taxable Ordinary Income          27,450   37,450   47,450

Code: Select all

 42  Ordinary Income @ 39.6%               0        0        0
 43  Ordinary Income @ 35.0%               0        0        0
 44  Ordinary Income @ 33.0%               0        0        0
 45  Ordinary Income @ 28.0%               0        0        0
 46  Ordinary Income @ 25.0%               0        0   10,000
 47  Ordinary Income @ 15.0%          18,225   28,225   28,225
 48  Ordinary Income @ 10.0%           9,225    9,225    9,225
 49  QDI & LTCG @ 20%                      0        0        0
 50  QDI & LTCG @ 15%                      0   10,000   10,000
 51  QDI & LTCG @ 0%                  10,000        0        0

Code: Select all

 52  Tax on Ordinary Income @ 39.6%        0        0        0
 53  Tax on Ordinary Income @ 35.0%        0        0        0
 54  Tax on Ordinary Income @ 33.0%        0        0        0
 55  Tax on Ordinary Income @ 28.0%        0        0        0
 56  Tax on Ordinary Income @ 25.0%        0        0    2,500
 57  Tax on Ordinary Income @ 15.0%    2,734    4,234    4,234
 58  Tax on Ordinary Income @ 10.0%      923      923      923
 59  Tax on QDI & LTCG @ 20%               0        0        0
 60  Tax on QDI & LTCG @ 15%               0    1,500    1,500
 61  Total Tax                         3,656    6,656    9,156
 62  Change in tax                              3,000    2,500
 63  Change in non-SS Inc LTCG QDI             10,000   10,000
 64  Marginal Rate                              30.0%    25.0%
If anyone is interested in duplicating this spreadsheet, here are the steps:
  • Copy and paste three times from below at cells A1, B1, and C1 of an empty sheet.
  • Enter Filing Status ("Single" or "Joint"), tax exempt interest, non-SS ordinary income, LTCG & QDI, and Social Security benefits into cells B25:B29.
  • Enter Deductions and Exemptions into cells B30:B31. Enter "Std" to use the default amounts or a number to use a non-standard amount.
Select All, Copy, and Paste at Cell A1

Code: Select all

Filing Status
"Std" Deduction
"Std" Exemption
Social Security 50% threshhold
Social Security 85% threshhold
0.1
0.15
0.25
0.28
0.33
0.35
0.396
=A4
=A5
=A12
=A11
=A10
=A9
=A8
=A7
=A6
0.2
0.15
0
Single or Joint Return
Tax exempt interest
Non-SS Ordinary Income
LTCG & QDI
Social Security Benefits
Deductions
Exemption
Deductions plus Exemption
Relevant Income for SS Calc
50% SS Taxable
85% SS Taxable
Total SS Taxable
Percent SS Taxable
Adjusted Gross Income
Taxable Income
Taxable QDI & LTCG
Taxable Ordinary Income
="Ordinary Income @ "&TEXT(A15,"#0.0%")
="Ordinary Income @ "&TEXT(A16,"#0.0%")
="Ordinary Income @ "&TEXT(A17,"#0.0%")
="Ordinary Income @ "&TEXT(A18,"#0.0%")
="Ordinary Income @ "&TEXT(A19,"#0.0%")
="Ordinary Income @ "&TEXT(A20,"#0.0%")
="Ordinary Income @ "&TEXT(A21,"#0.0%")
="QDI & LTCG @ "&TEXT(A22,"#0%")
="QDI & LTCG @ "&TEXT(A23,"#0%")
="QDI & LTCG @ "&TEXT(A24,"#0%")
="Tax on "&A42
="Tax on "&A43
="Tax on "&A44
="Tax on "&A45
="Tax on "&A46
="Tax on "&A47
="Tax on "&A48
="Tax on "&A49
="Tax on "&A50
Total Tax
Change in tax
Change in SS, non SS, LTCG QDI
Marginal Rate
Select All, Copy, and Paste at Cell B1

Code: Select all

Single
7850
4000
25000
34000
0
9225
37450
90750
189300
411500
413200
=HLOOKUP(B$25,$B$1:$C$5,4,FALSE)
=HLOOKUP(B$25,$B$1:$C$5,5,FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A15)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A16)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A17)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A18)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A19)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A20)+ROW(A$15),FALSE)
=HLOOKUP(B$25,$B$1:$C$12,12-ROW(A21)+ROW(A$15),FALSE)
=B15
=B19
=B21
Single
0
39300
10000

Std
Std
=IF(ISNUMBER(B30),B30,HLOOKUP(B25,$B$1:$C$3,2,FALSE))+IF(ISNUMBER(B31),B31,HLOOKUP(B25,$B$1:$C$3,3,FALSE))
=B26+B27+B28+B29/2
=MIN(50%*B29,MAX(0,50%*MIN(B14-B13,B33-B13)))
=MIN(85%*B29-B34,85%*MAX(0,B33-B14))
=B34+B35
=IF(B29=0,0,B36/B29)
=B27+B28+B36
=MAX(0,B38-B32)
=IF(ISNUMBER(B28),MIN(B28,B39),0)
=MAX(0,B39-B40)
=MAX(0,B$41-B15)
=MAX(0,B$41-B16)-SUM(B$42:B42)
=MAX(0,B$41-B17)-SUM(B$42:B43)
=MAX(0,B$41-B18)-SUM(B$42:B44)
=MAX(0,B$41-B19)-SUM(B$42:B45)
=MAX(0,B$41-B20)-SUM(B$42:B46)
=MAX(0,B$41-B21)-SUM(B$42:B47)
=MAX(0,MIN(B$40,B$39-B22))
=MAX(0,MIN(B$40,B$39-B23))-SUM(B$49:B49)
=MAX(0,MIN(B$40,B$39-B24))-SUM(B$49:B50)
=B42*$A15
=B43*$A16
=B44*$A17
=B45*$A18
=B46*$A19
=B47*$A20
=B48*$A21
=B49*$A22
=B50*$A23
=SUM(B52:B60)
Select All, Copy, and Paste at Cell C1

Code: Select all

Joint
15100
8000
32000
44000
0
18450
74900
151200
230450
411500
464850
To repeat the calculation for other assumptions follow these steps:
  • Select cells B13:B61 and copy right into column C.
  • Update assumptions in cells C25:C31.
  • Copy and paste the following formulas at cell C62.
  • To add more columns, copy cells C13:C64 to the right and update assumptions in rows 25:31.
Select All, Copy, and Paste at Cell C62

Code: Select all

=C61-B61
=SUM(C27:C29)-SUM(B27:B29)
=IF(C63=0,0,C62/C63)
The spreadsheet certainly isn't complete. E.g., It does handle Social Security Income, but it ignores the Alternative Minimum Tax. There are probably some bugs lurking. For anything important, you should confirm with something like TaxCaster.

Edit 9/28/2015 to revise spreadsheet formulas for copying and pasting. Fixes SS calc bug and makes assumptions more flexible.
Last edited by #Cruncher on Mon Sep 28, 2015 7:00 pm, edited 2 times in total.
User avatar
Rager1
Posts: 999
Joined: Fri Jun 01, 2007 12:03 pm

Re: AGI, capital gains, and income interaction?

Post by Rager1 »

#Cruncher,

Once again, your willingness to share your expertise on this Board is amazing! I always look forward to anything that you post.

Thank you!

Ed
skibum
Posts: 27
Joined: Sat Feb 15, 2014 3:08 pm

Re: AGI, capital gains, and income interaction?

Post by skibum »

I found the article by Michael Kitces at link below did a nice job of explaining the interaction of income, dividends, and capital gains at the top of the 15% bracket. Similar to the stack ups already shown, with a few examples to help clarify.

https://www.kitces.com/blog/understandi ... -in-basis/
heyyou
Posts: 4461
Joined: Tue Feb 20, 2007 3:58 pm

Re: AGI, capital gains, and income interaction?

Post by heyyou »

For 2015 marital status Single, $4000 personal exemption, $6300 standard deduction, so the first $10300 of your income has an Adjusted Gross Income (AGI) of zero. For Married filing Jointly (MFJ), double every number above.

For Single tax filers, the next $9225 of AGI income to the top of the the 10% tax bracket, the tax is 922.50, on your first (10300 + 9225) $19525 of total income, effective rate 4.7% at the top of the bracket.
Next is the 15% bracket to 37,450 of AGI at the top of the bracket. The tax is 5156.25 on your first (10300 + 37,450) $47,750, effective rate of 10.8% at the top of the bracket.
The 25% bracket upper limit is 90,750 of AGI, there the tax is 18481.25 on (10300 + 90750) $101050, effective rate of 18.35%.
Your effective rate will be noticeably less than the top rate of whatever bracket you are in.

Note that only the portion of your cap gains that are more than the 15% bracket are taxed. Any cap gains in the 15% bracket are not taxed, only those that spill into the 25% bracket are then taxed at 15%. So your AGI is taxed then your cap gains are inspected to see how much of them are taxed, if any.

Some good Fairmark.com links:
http://fairmark.com/general-taxation/re ... inflation/
http://fairmark.com/general-taxation/re ... schedules/
but be careful to scroll to the correct table for your tax filing status.
kaneohe
Posts: 6786
Joined: Mon Sep 22, 2008 12:38 pm

Re: AGI, capital gains, and income interaction?

Post by kaneohe »

heyyou wrote:For 2015 marital status Single, $4000 personal exemption, $6300 standard deduction, so the first $10300 of your income has an Adjusted Gross Income (AGI) of zero. For Married filing Jointly (MFJ), double every number above.
..............................................................
did you mean that the taxable income is zero? From the 1040, http://www.irs.gov/pub/irs-pdf/f1040.pdf, AGI=Ttl income less adjustments;
taxable income = AGI less deductions and exemptions.
User avatar
Artsdoctor
Posts: 6063
Joined: Thu Jun 28, 2012 3:09 pm
Location: Los Angeles, CA

Re: AGI, capital gains, and income interaction?

Post by Artsdoctor »

heyyou wrote:For 2015 marital status Single, $4000 personal exemption, $6300 standard deduction, so the first $10300 of your income has an Adjusted Gross Income (AGI) of zero. For Married filing Jointly (MFJ), double every number above.
This is not accurate. The adjusted gross income is at the bottom of the first page of your 1040. On the second page, you then enter your exemptions and deductions. It is on the second page that you may well have a Taxable Income of zero, but that is very different than having an AGI of zero.
Post Reply